# Author: Finn Lidbetter

INT(1, 200000, n) NEWLINE
SET(passengermax=0)
SET(locationmax=0)
REPI(i, n)
    SET(passengers[i+1]=0)
END
REP(n*2)
    INT(1,n,passenger) SPACE INT(1, n*2, location) NEWLINE
    SET(passengers[passenger]=passengers[passenger]+1)
    # The passenger number appears at most twice.
    ASSERT(passengers[passenger]<=2)
    IF(passenger > passengermax)
        # A new passenger number is the next smallest passenger.
        ASSERT(passenger == passengermax + 1)
        SET(passengermax=passenger)
    END
    IF(location > locationmax)
        # A new location number is the next smallest location.
        ASSERT(location == locationmax + 1)
        SET(locationmax=location)
    END
END
# Each passenger number appears exactly twice.
REPI(i, n)
    ASSERT(passengers[i+1]==2)
END

# https://github.com/DOMjudge/checktestdata
# https://github.com/DOMjudge/checktestdata/blob/main/doc/format-spec.md
#
# Quick reference:
#
# integer  := 0|-?[1-9][0-9]*
# float    := -?[0-9]+(\.[0-9]+)?([eE][+-]?[0-9]+)?
# string   := ".*"
# varname  := [a-z][a-z0-9]*
# variable := <varname> | <varname> '[' <expr> [',' <expr> ...] ']'
# value    := <integer> | <float> | <string> | <variable> | <function>
# compare  := '<' | '>' | '<=' | '>=' | '==' | '!='
# logical  := '&&' | '||'
# expr     := <term> | <expr> [+-] <term>
# term     := <factor> | <term> [*%/] <factor>
# factor   := <value> | '-' <factor> | '(' <expr> ')' | <factor> '^' <factor>
# test     := '!' <test> | <test> <logical> <test> | '(' <test> ')' | <expr> <compare> <expr> | <testcommand>
#
# Test Commands:
# MATCH(<value> str)
# ISEOF
# UNIQUE(<varname> a [,<varname> b ...])
# INARRAY(<value> val, <varname> var)
# 
# Functions:
# STRLEN(<value> str)
#
# Commands:
# SPACE / NEWLINE
# EOF
# INT(<expr> min, <expr> max [, <variable> name])
# FLOAT(<expr> min, <expr> max [, <variable> name [, option]])
# FLOATP(<expr> min, <expr> max, <value> mindecimals, <value> maxdecimals, [, <variable> name [, option]])
# STRING(<value> str)
# REGEX(<value> str [, <variable> name])
# ASSERT(<test> condition)
# SET(<variable> name '=' <expr> value[, ...])
# UNSET(<varname> a [,<varname> b ...])
# REP(<expr> count [,<command> separator]) [<command>...] END
# REPI(<variable> i, <expr> count [,<command> separator]) [<command>...] END
# WHILE(<test> condition [,<command> separator]) [<command>...] END
# WHILEI(<variable> i, <test> condition [,<command> separator]) [<command>...] END
# IF(<test> cond) [<command> cmds1...] [ELSE [<command> cmds2...]] END